The Diamond-Flowered Orchid — 10 of 14

Chapter 4 - References

Section 1 - Leeches

A person can be leeched or unleeched. The player is unleeched.

legs are a kind of supporter. Legs are part of every person.

Understand "leg" as legs.

A person has a number called health. The health of the player is 10.

leeches are a thing with description "Some leeches are stuck to your legs sucking blood. They don't make you feel great.".

Understand "leech" as leeches.

Every turn when the player is leeched:

say "You feel something on your legs. [if the health of the player is less than 6]You feel weak. Maybe you should [bold type]look at legs[roman type] to see what's wrong.[end if][if the health of the player is less than 3] Maybe you should [bold type]remove leeches[roman type].[end if]";

Decrease the health of the player by 1;

If the health of the player is 0:

end the story finally saying "You feel too weak to go on. You collapse and don't get up again.";

Every turn when the player has been unleeched for 3 turns and the location of the player is not Crashed Helicopter:

if a random chance of 1 in 7 succeeds:

now the player is leeched;

move leeches to the location of the player;

try silently taking leeches;

try silently putting leeches on a random legs that is part of the player;

Instead of taking leeches when leeches are on legs:

Remove leeches from play;

Now the player is unleeched;

if Vorple is supported:

play sound effect "leeches.mp3";

Now the health of the player is 10;

Say "Ah, that feels better!";

Understand the command "remove" as something new.

Understand "remove [something]" as taking.

Carry out examining legs:

if the player is leeched:

say "There are leeches on your legs!";

otherwise:

say "Your legs look perfectly fine.";

now examine text printed is true.

The examine supporters rule does nothing when examining legs.